UHD Cards Compute Shader Bug

[Mutwe]

Hello,
I've built an pretty simple HLSL simplex noise generation shader and have resieved multiple reports from users with HD/UHD cards (HD 520, HD 620, and UHD 630 confirmed).
No Nvidia / AMD cards seem to replicate this issue, other Intel cards (tested w/5000 series) also work normally.

In the provided example I've oversimplified some aspects of this shader in the hopes of identifying the problem (numthreads, use of RWStructuredBuffer over RWTexture2D) with no effect.

I've included all Code (Shader, #include {Which I did not build}, and C# method).
I've also attached output example images from user reports.

Shader:

#pragma kernel CSMain
#include "noiseSimplex.cginc"  
         
struct SettingsData
{                      
    uint _Octaves;  
    float _NoiseScale;
    float _Amplitude;
    float _Persistence;
    float _Lunacrity;
    float _Softness;  
    float _MaskScale;
    float _MaskStrength;
    float _MaskPower;
};
           
uniform StructuredBuffer<SettingsData> _Buffer : register(ps_3_0, t1); 
RWStructuredBuffer<float4> _Output;
                          
float4 _Position; 
float _Time;
float _Size;
int _Resolution;  
int _Padding;
int _Seed;
 
float SampleNoise(float3 position, int seed, float time)
{                                        
    return snoise(float4(position.x, position.y, (seed * .77), time));
}

half GeneratePoint(SettingsData data, half3 position)
{                                            
    uint octaves = data._Octaves;
    float amplitude = data._Amplitude;
    float lunacrity = data._Lunacrity;    
    half persistence = data._Persistence;   
    half maskScale = data._MaskScale;
    half maskStr = data._MaskStrength;
    half smoothMask = data._MaskPower * .5;
    half noiseScale = data._NoiseScale; 
    half softness = data._Softness;
    float frequency = 1.0;
    float maxHeight = 1.0;
    float value = 0.0; 
    float mask =  0.0; 
    int seed = _Seed;                          
          
    float3 pos = position;
    pos *= _Size;
    pos += _Position.xyz;
    pos -= .5 * _Size;    
    
    if (maskScale <= 0)     maskScale = 1;
    if (noiseScale <= 0)    noiseScale = 1;
    
    for (uint i = 0; i < octaves; i++)
    {                      
        seed = (_Seed - i * octaves);
              
        value += SampleNoise(pos * frequency / noiseScale, seed, _Time) * amplitude;   
        mask += SampleNoise(pos * frequency / maskScale / noiseScale, seed, _Time + 100) * amplitude;                  
        
        frequency *= lunacrity;
        amplitude *= persistence;
        maxHeight += amplitude * amplitude;
    }
    
    value /= maxHeight;                                    
    mask /= maxHeight; 
    
    // - Apply Masking
    mask = abs((mask + 1) * .5f);  
    
    if (maskStr > 0) mask = pow(mask, maskStr); 
    
    float min  = .5 - smoothMask;
    float max = .5f + smoothMask;
    mask = smoothstep(.5 - smoothMask, .5f + smoothMask, clamp(mask, min, max));
    
    value = value * mask;
    
    if (value > 1)          value = -1;
    if (value < -1)         value = 1;
    
    // - Apply Smoothing 
    min = -softness;
    max = softness;
    value *= max + 1;         
    value = smoothstep(min, max, clamp(value, min, max)); 
    
    return saturate(value);
}

[numthreads(1, 1, 1)]
void CSMain (uint3 id : SV_DispatchThreadID)
{                     
    float res = _Resolution - _Padding;
    float3 pos = half3(id.x, id.y, id.z) / res;      
    float4 color;
    
    color.r = GeneratePoint(_Buffer[0], pos);
    color.g = GeneratePoint(_Buffer[1], pos);
    color.b = GeneratePoint(_Buffer[2], pos);
    color.a = GeneratePoint(_Buffer[3], pos);       
        
    _Output[id.y * _Resolution + id.x] = color;
}

noiseSimlex.cginc include:

#ifndef NOISE_SIMPLEX_FUNC
#define NOISE_SIMPLEX_FUNC
/*

Description:
	Array- and textureless CgFx/HLSL 2D, 3D and 4D simplex noise functions.
	a.k.a. simplified and optimized Perlin noise.

	The functions have very good performance
	and no dependencies on external data.

	2D - Very fast, very compact code.
	3D - Fast, compact code.
	4D - Reasonably fast, reasonably compact code.

------------------------------------------------------------------

Ported by:
	Lex-DRL
	I've ported the code from GLSL to CgFx/HLSL for Unity,
	added a couple more optimisations (to speed it up even further)
	and slightly reformatted the code to make it more readable.

Original GLSL functions:
	https://github.com/ashima/webgl-noise
	Credits from original glsl file are at the end of this cginc.

------------------------------------------------------------------

Usage:

	float ns = snoise(v);
	// v is any of: float2, float3, float4

	Return type is float.
	To generate 2 or more components of noise (colorful noise),
	call these functions several times with different
	constant offsets for the arguments.
	E.g.:

	float3 colorNs = float3(
		snoise(v),
		snoise(v + 17.0),
		snoise(v - 43.0),
	);


Remark about those offsets from the original author:

	People have different opinions on whether these offsets should be integers
	for the classic noise functions to match the spacing of the zeroes,
	so we have left that for you to decide for yourself.
	For most applications, the exact offsets don't really matter as long
	as they are not too small or too close to the noise lattice period
	(289 in this implementation).

*/

// 1 / 289
#define NOISE_SIMPLEX_1_DIV_289 0.00346020761245674740484429065744f

float mod289(float x) {
	return x - floor(x * NOISE_SIMPLEX_1_DIV_289) * 289.0;
}

float2 mod289(float2 x) {
	return x - floor(x * NOISE_SIMPLEX_1_DIV_289) * 289.0;
}

float3 mod289(float3 x) {
	return x - floor(x * NOISE_SIMPLEX_1_DIV_289) * 289.0;
}

float4 mod289(float4 x) {
	return x - floor(x * NOISE_SIMPLEX_1_DIV_289) * 289.0;
}


// ( x*34.0 + 1.0 )*x =
// x*x*34.0 + x
float permute(float x) {
	return mod289(
		x*x*34.0 + x
	);
}

float3 permute(float3 x) {
	return mod289(
		x*x*34.0 + x
	);
}

float4 permute(float4 x) {
	return mod289(
		x*x*34.0 + x
	);
}



float taylorInvSqrt(float r) {
	return 1.79284291400159 - 0.85373472095314 * r;
}

float4 taylorInvSqrt(float4 r) {
	return 1.79284291400159 - 0.85373472095314 * r;
}



float4 grad4(float j, float4 ip)
{
	const float4 ones = float4(1.0, 1.0, 1.0, -1.0);
	float4 p, s;
	p.xyz = floor(frac(j * ip.xyz) * 7.0) * ip.z - 1.0;
	p.w = 1.5 - dot(abs(p.xyz), ones.xyz);

	// GLSL: lessThan(x, y) = x < y
	// HLSL: 1 - step(y, x) = x < y
	s = float4(
		1 - step(0.0, p)
		);

	// Optimization hint Dolkar
	// p.xyz = p.xyz + (s.xyz * 2 - 1) * s.www;
	p.xyz -= sign(p.xyz) * (p.w < 0);

	return p;
}



// ----------------------------------- 2D -------------------------------------

float snoise(float2 v)
{
	const float4 C = float4(
		0.211324865405187, // (3.0-sqrt(3.0))/6.0
		0.366025403784439, // 0.5*(sqrt(3.0)-1.0)
		-0.577350269189626, // -1.0 + 2.0 * C.x
		0.024390243902439  // 1.0 / 41.0
		);

	// First corner
	float2 i = floor(v + dot(v, C.yy));
	float2 x0 = v - i + dot(i, C.xx);

	// Other corners
		// float2 i1 = (x0.x > x0.y) ? float2(1.0, 0.0) : float2(0.0, 1.0);
		// Lex-DRL: afaik, step() in GPU is faster than if(), so:
		// step(x, y) = x <= y

		// Optimization hint Dolkar
		//int xLessEqual = step(x0.x, x0.y); // x <= y ?
		//int2 i1 =
		//    int2(1, 0) * (1 - xLessEqual) // x > y
		//    + int2(0, 1) * xLessEqual // x <= y
		//;
		//float4 x12 = x0.xyxy + C.xxzz;
		//x12.xy -= i1;

	float4 x12 = x0.xyxy + C.xxzz;
	int2 i1 = (x0.x > x0.y) ? float2(1.0, 0.0) : float2(0.0, 1.0);
	x12.xy -= i1;

	// Permutations
	i = mod289(i); // Avoid truncation effects in permutation
	float3 p = permute(
		permute(
			i.y + float3(0.0, i1.y, 1.0)
		) + i.x + float3(0.0, i1.x, 1.0)
	);

	float3 m = max(
		0.5 - float3(
			dot(x0, x0),
			dot(x12.xy, x12.xy),
			dot(x12.zw, x12.zw)
			),
		0.0
	);
	m = m * m;
	m = m * m;

	// Gradients: 41 points uniformly over a line, mapped onto a diamond.
	// The ring size 17*17 = 289 is close to a multiple of 41 (41*7 = 287)

	float3 x = 2.0 * frac(p * C.www) - 1.0;
	float3 h = abs(x) - 0.5;
	float3 ox = floor(x + 0.5);
	float3 a0 = x - ox;

	// Normalise gradients implicitly by scaling m
	// Approximation of: m *= inversesqrt( a0*a0 + h*h );
	m *= 1.79284291400159 - 0.85373472095314 * (a0*a0 + h * h);

	// Compute final noise value at P
	float3 g;
	g.x = a0.x * x0.x + h.x * x0.y;
	g.yz = a0.yz * x12.xz + h.yz * x12.yw;
	return 130.0 * dot(m, g);
}

// ----------------------------------- 3D -------------------------------------

float snoise(float3 v)
{
	const float2 C = float2(
		0.166666666666666667, // 1/6
		0.333333333333333333  // 1/3
		);
	const float4 D = float4(0.0, 0.5, 1.0, 2.0);

	// First corner
	float3 i = floor(v + dot(v, C.yyy));
	float3 x0 = v - i + dot(i, C.xxx);

	// Other corners
	float3 g = step(x0.yzx, x0.xyz);
	float3 l = 1 - g;
	float3 i1 = min(g.xyz, l.zxy);
	float3 i2 = max(g.xyz, l.zxy);

	float3 x1 = x0 - i1 + C.xxx;
	float3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
	float3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y

// Permutations
	i = mod289(i);
	float4 p = permute(
		permute(
			permute(
				i.z + float4(0.0, i1.z, i2.z, 1.0)
			) + i.y + float4(0.0, i1.y, i2.y, 1.0)
		) + i.x + float4(0.0, i1.x, i2.x, 1.0)
	);

	// Gradients: 7x7 points over a square, mapped onto an octahedron.
	// The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
	float n_ = 0.142857142857; // 1/7
	float3 ns = n_ * D.wyz - D.xzx;

	float4 j = p - 49.0 * floor(p * ns.z * ns.z); // mod(p,7*7)

	float4 x_ = floor(j * ns.z);
	float4 y_ = floor(j - 7.0 * x_); // mod(j,N)

	float4 x = x_ * ns.x + ns.yyyy;
	float4 y = y_ * ns.x + ns.yyyy;
	float4 h = 1.0 - abs(x) - abs(y);

	float4 b0 = float4(x.xy, y.xy);
	float4 b1 = float4(x.zw, y.zw);

	//float4 s0 = float4(lessThan(b0,0.0))*2.0 - 1.0;
	//float4 s1 = float4(lessThan(b1,0.0))*2.0 - 1.0;
	float4 s0 = floor(b0)*2.0 + 1.0;
	float4 s1 = floor(b1)*2.0 + 1.0;
	float4 sh = -step(h, 0.0);

	float4 a0 = b0.xzyw + s0.xzyw*sh.xxyy;
	float4 a1 = b1.xzyw + s1.xzyw*sh.zzww;

	float3 p0 = float3(a0.xy, h.x);
	float3 p1 = float3(a0.zw, h.y);
	float3 p2 = float3(a1.xy, h.z);
	float3 p3 = float3(a1.zw, h.w);

	//Normalise gradients
	float4 norm = taylorInvSqrt(float4(
		dot(p0, p0),
		dot(p1, p1),
		dot(p2, p2),
		dot(p3, p3)
		));
	p0 *= norm.x;
	p1 *= norm.y;
	p2 *= norm.z;
	p3 *= norm.w;

	// Mix final noise value
	float4 m = max(
		0.6 - float4(
			dot(x0, x0),
			dot(x1, x1),
			dot(x2, x2),
			dot(x3, x3)
			),
		0.0
	);
	m = m * m;
	return 42.0 * dot(
		m*m,
		float4(
			dot(p0, x0),
			dot(p1, x1),
			dot(p2, x2),
			dot(p3, x3)
			)
	);
}

// ----------------------------------- 4D -------------------------------------

float snoise(float4 v)
{
	const float4 C = float4(
		0.138196601125011, // (5 - sqrt(5))/20 G4
		0.276393202250021, // 2 * G4
		0.414589803375032, // 3 * G4
		-0.447213595499958  // -1 + 4 * G4
		);

	// First corner
	float4 i = floor(
		v +
		dot(
			v,
			0.309016994374947451 // (sqrt(5) - 1) / 4
		)
	);
	float4 x0 = v - i + dot(i, C.xxxx);

	// Other corners

	// Rank sorting originally contributed by Bill Licea-Kane, AMD (formerly ATI)
	float4 i0;
	float3 isX = step(x0.yzw, x0.xxx);
	float3 isYZ = step(x0.zww, x0.yyz);
	i0.x = isX.x + isX.y + isX.z;
	i0.yzw = 1.0 - isX;
	i0.y += isYZ.x + isYZ.y;
	i0.zw += 1.0 - isYZ.xy;
	i0.z += isYZ.z;
	i0.w += 1.0 - isYZ.z;

	// i0 now contains the unique values 0,1,2,3 in each channel
	float4 i3 = saturate(i0);
	float4 i2 = saturate(i0 - 1.0);
	float4 i1 = saturate(i0 - 2.0);

	//    x0 = x0 - 0.0 + 0.0 * C.xxxx
	//    x1 = x0 - i1  + 1.0 * C.xxxx
	//    x2 = x0 - i2  + 2.0 * C.xxxx
	//    x3 = x0 - i3  + 3.0 * C.xxxx
	//    x4 = x0 - 1.0 + 4.0 * C.xxxx
	float4 x1 = x0 - i1 + C.xxxx;
	float4 x2 = x0 - i2 + C.yyyy;
	float4 x3 = x0 - i3 + C.zzzz;
	float4 x4 = x0 + C.wwww;

	// Permutations
	i = mod289(i);
	float j0 = permute(
		permute(
			permute(
				permute(i.w) + i.z
			) + i.y
		) + i.x
	);
	float4 j1 = permute(
		permute(
			permute(
				permute(
					i.w + float4(i1.w, i2.w, i3.w, 1.0)
				) + i.z + float4(i1.z, i2.z, i3.z, 1.0)
			) + i.y + float4(i1.y, i2.y, i3.y, 1.0)
		) + i.x + float4(i1.x, i2.x, i3.x, 1.0)
	);

	// Gradients: 7x7x6 points over a cube, mapped onto a 4-cross polytope
	// 7*7*6 = 294, which is close to the ring size 17*17 = 289.
	const float4 ip = float4(
		0.003401360544217687075, // 1/294
		0.020408163265306122449, // 1/49
		0.142857142857142857143, // 1/7
		0.0
		);

	float4 p0 = grad4(j0, ip);
	float4 p1 = grad4(j1.x, ip);
	float4 p2 = grad4(j1.y, ip);
	float4 p3 = grad4(j1.z, ip);
	float4 p4 = grad4(j1.w, ip);

	// Normalise gradients
	float4 norm = taylorInvSqrt(float4(
		dot(p0, p0),
		dot(p1, p1),
		dot(p2, p2),
		dot(p3, p3)
		));
	p0 *= norm.x;
	p1 *= norm.y;
	p2 *= norm.z;
	p3 *= norm.w;
	p4 *= taylorInvSqrt(dot(p4, p4));

	// Mix contributions from the five corners
	float3 m0 = max(
		0.6 - float3(
			dot(x0, x0),
			dot(x1, x1),
			dot(x2, x2)
			),
		0.0
	);
	float2 m1 = max(
		0.6 - float2(
			dot(x3, x3),
			dot(x4, x4)
			),
		0.0
	);
	m0 = m0 * m0;
	m1 = m1 * m1;

	return 49.0 * (
		dot(
			m0*m0,
			float3(
				dot(p0, x0),
				dot(p1, x1),
				dot(p2, x2)
				)
		) + dot(
			m1*m1,
			float2(
				dot(p3, x3),
				dot(p4, x4)
				)
		)
		);
}



//                 Credits from source glsl file:
//
// Description : Array and textureless GLSL 2D/3D/4D simplex
//               noise functions.
//      Author : Ian McEwan, Ashima Arts.
//  Maintainer : ijm
//     Lastmod : 20110822 (ijm)
//     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
//               Distributed under the MIT License. See LICENSE file.
//               https://github.com/ashima/webgl-noise
//
//
//           The text from LICENSE file:
//
//
// Copyright (C) 2011 by Ashima Arts (Simplex noise)
// Copyright (C) 2011 by Stefan Gustavson (Classic noise)
//
// Permission is hereby granted, free of charge, to any person obtaining a copy
// of this software and associated documentation files (the "Software"), to deal
// in the Software without restriction, including without limitation the rights
// to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
// copies of the Software, and to permit persons to whom the Software is
// furnished to do so, subject to the following conditions:
//
// The above copyright notice and this permission notice shall be included in
// all copies or substantial portions of the Software.
//
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
// IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
// OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
// THE SOFTWARE.
#endif

public void GenerateNoise(Vector2 position, int seed, int padding, float size, int resolution, System.Action<Vector4[,]> callback)
{
Initialize();

var data = new BufferData[] { new BufferData(altitudeSettings), new BufferData(climateSettings), new BufferData(temperatureSettings), new BufferData(nutrientSettings) };

GenerateHandle(position, seed, padding, size, resolution, data, callback);
}

private CombuteBufferConversionHandle GenerateHandle(Vector2 position, int seed, int padding, float size, int resolution, BufferData[] settings, System.Action<Vector4[,]> callback)
{
var buffer = new ComputeBuffer(resolution * resolution, 4 * sizeof(float), ComputeBufferType.Structured, ComputeBufferMode.Immutable);

GenerateNoise(buffer, position, seed, padding, size, resolution, settings);
return new CombuteBufferConversionHandle(ref buffer, callback);
}

private void GenerateNoise(ComputeBuffer buffer, Vector2 position, int seed, int padding, float size, int resolution, BufferData[] settings)
{
	if (noiseShader != null)
{
var noiseHandle = noiseShader.FindKernel("CSMain");
noiseShader.SetInt("_Padding", padding);
noiseShader.SetInt("_Resolution", resolution);
noiseShader.SetInt("_Seed", seed % short.MaxValue);
noiseShader.SetVector("_Position", position);
noiseShader.SetFloat("_Size", size);
noiseShader.SetFloat("_Time", time);

var attributeBuffer = new ComputeBuffer(4, BufferData.DataSize, ComputeBufferType.Structured, ComputeBufferMode.Immutable);

attributeBuffer.SetData(settings);
noiseShader.SetBuffer(noiseHandle, "_Buffer", attributeBuffer);

if (buffer != null) noiseShader.SetBuffer(noiseHandle, "_Output", buffer);
noiseShader.Dispatch(noiseHandle, resolution, resolution, 1);
attributeBuffer.Dispose();
}
}

private class CombuteBufferConversionHandle
		{
			private ComputeBuffer inputBuffer;
			protected System.Action<Vector4[,]> callback;
			protected NativeArray<Vector4> tempBuffer;

			public CombuteBufferConversionHandle(ref ComputeBuffer inputBuffer, System.Action<Vector4[,]> callback)
			{
				this.inputBuffer = inputBuffer;
				this.callback = callback;

				tempBuffer = new NativeArray<Vector4>(inputBuffer.count, Allocator.Persistent);

				AsyncGPUReadback.RequestIntoNativeArray(ref tempBuffer, inputBuffer, OnRequestCallback);
			}

			protected void OnRequestCallback(AsyncGPUReadbackRequest request)
			{
				var count = (int)Mathf.Sqrt(inputBuffer.count);
				var result = new Vector4[count, count];

				if (!request.hasError && tempBuffer.IsCreated)
				{
					var index = 0;

					for (int y = 0; y < count; y++)
					{
						for (int x = 0; x < count; x++)
						{
							var i = index;

							result[x, y] = tempBuffer[i];
							index++;
						}
					}
				}

				else Debug.LogWarning("GPU readback error detected.");

				if (callback != null && callback.Target != null) callback.Invoke(result);
				callback = null;

				Dispose();
			}

			public void Dispose()
			{
				if (tempBuffer.IsCreated) tempBuffer.Dispose();
				if (inputBuffer != null) inputBuffer.Release();
			}
		}

		[System.Serializable]
		private struct BufferData
		{
			public uint _Octaves;
			public float _NoiseScale;
			public float _Amplitude;
			public float _Persistence;
			public float _Lunacrity;
			public float _Softness;
			public float _MaskScale;
			public float _MaskStrength;
			public float _MaskPower;

			public static int DataSize => 8 * sizeof(float) + sizeof(uint);

			public BufferData(NoiseLayerData data)
			{
				_Octaves = data.octaves;
				_NoiseScale = data.scale;
				_Amplitude = data.amplitude;
				_Persistence = data.persistance;
				_Lunacrity = data.lunacrity;
				_Softness = data.softness;
				_MaskScale = data.maskScale;
				_MaskStrength = data.maskStrength;
				_MaskPower = data.maskPower;
			}
		}

[RamyerM_Intel]

Hello Mutwe

I have read your concern and I want to let you know that we have a dedicated forum for this type of issue, where you can get faster answers. I am moving this to the Developing Games on Intel Graphics Forum for you.

Ramyer M.

Intel Customer Support Technician 

[karen_intel]

Hii @Mutwe welcome to our Intel Game Developer forum

Thank you for sharing all these details, could you please share a way to contact you directly? Discord is what we generally use

I'm also noticing you have mentioned some iGFX models also, FYI we need to verify it in other generations to confirm compliance in newest systems as well

Stay tuned!

Karen

[Arturo_Intel]

Hi @Mutwe 

I was trying to run the code you share without any luck!

Could you please share the whole project or instructions to run the demo code.

I'm not sure if you are using visual studio or something else. 

Also, please share your discord (or other 1:1 contact method you prefer) to this email:

arturo.medina.mendoza@intel.com

Thanks in advance,

-- r2

[Mutwe]

Hey all!
Thanks for the replay and putting me in the right place. 

Discord contact for @karen_intel + @Arturo_Intel's request : Mutwe#7726

I'll take some time now and create a dedicated project to share. Should have it ready shortly

[Mutwe]

I've built a package with all / only required files + some light cleanup to simplify testing.

Important Info: 
Engine: Unity Version 2021.3.30f1 (But any version older than 2019 should work)
IDE: Visual Studio 2022

- The sample scene (_Main) has all required fields setup and should be fully functional without any extra work.
- The package can be opened in a new project or any existing Unity project.
- The project has no other Unity package dependencies.

[karen_intel]

@Mutwe thank you for your prompt reply! 

We'll get hands-on and let you know if we have questions/our findings. Talk to you soon

Karen

[karen_intel]

Hi @Mutwe about your latest post:

I was able to run it in a UHD 770, Intel ARC A750 and NVIDIA 3060 and I'm seeing the exact same result in all of them when loading the shaders.
Can you confirm if this is what we're looking for and if that's how it should look? If this is not how it should look, please send me a video so I can continue doing my testing.



About the other products were this project was tested and that you have listed at the beginning of this post, all of them have reached EOL support.

Please have a look at the link above for more information.

If the project you're working on has a very wide community and the impact of this issue is affecting many users please let us know. We'll be making sure to follow this one up once we're able to repro in our supported products.

Talk to you soon

Karen

[Mutwe · Accepted solution]

Thanks @karen_intel, This output is correct. It's good to see that this issue is fixed on newer drivers (assuming it's a driver issue).
My project is Adapt (https://store.steampowered.com/app/888780/Adapt/), I am an indie developer, I'd estimated the project's reach is moderate at best by intel standards, but I've received approximately 10 - 20 unique users experiencing this issue since implementing the system a couple of months ago. All confirmed cased were using 500 or 600 series cards.

Unfortunately I don't have a machine sporting one of these GPUs, so designing a fix is a slow game of blind darts with my users. I'm hopeful that the EOL team is able to find something; even if it's just a workaround on my end.

Thanks very much for your time and effort investigating this issue, and for the confirmation that at least it's resolved on modern hardware.

[karen_intel]

@Mutwe you're very welcome.

If you guys find anything else we can assist with (on supported HW) share this forum with them and we also support other community forums like IGCIT 

Best of luck with your current and future products!

Closing this thread as issue is not happening with newest GFX products and driver v.5379

Karen