링크가 복사됨
SunMesa wrote:.. But I'm so helpless with calling Windows functions from Fortran, I can't seem to get the syntax and/or type declarations right. ..
Any suggestions greatly appreciated!
@SunMesa,
My first suggestion will be to go through a book such as this one, especially chapter 12 on facilities in Fortran toward interoperability with C.
Secondly, you can make use of a Fortran module such as this one that includes interfaces to the couple of Windows API functions I suggested earlier in Quote #10.
module IWinAPI_m
use, intrinsic :: iso_c_binding, only : c_char, c_int, c_intptr_t, c_funptr
implicit none
!.. Public by default
public
!.. Mnemonics for types in Windows API functions
integer(c_int), parameter :: HMODULE = c_intptr_t !.. A handle to a module; base address in memory
integer(HMODULE), parameter :: NULL_HANDLE = int( 0, kind=kind(NULL_HANDLE) )
interface
function LoadLibrary(lpLibName) bind(C, name='LoadLibraryA') result(RetVal)
!DIR$ ATTRIBUTES STDCALL :: LoadLibrary
! https://msdn.microsoft.com/en-us/library/windows/desktop/ms684175(v=vs.85).aspx
! HMODULE WINAPI LoadLibrary(_In_ LPCTSTR lpFileName );
import :: c_char, HMODULE
!.. Argument list
character(kind=c_char, len=1), intent(in) :: lpLibName(*)
!.. Function result
integer(HMODULE) :: RetVal
end function LoadLibrary
function LoadStringA(hInstance, uID, lpBuffer, cchBufferMax) bind(C, name='LoadStringA') result(RetVal)
!DIR$ ATTRIBUTES STDCALL :: LoadStringA
! https://docs.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-loadstringa
! int LoadStringA(
! HINSTANCE hInstance,
! UINT uID,
! LPSTR lpBuffer,
! int cchBufferMax
! );
import :: HMODULE, c_int, c_char
!.. Argument list
integer(HMODULE), intent(in), value :: hInstance
integer(c_int), intent(in), value :: uID
character(kind=c_char,len=1) :: lpBuffer(*)
integer(c_int), intent(in), value :: cchBufferMax
!.. Function result
integer(c_int) :: RetVal
end function LoadStringA
end interface
end module IWinAPI_m
Then say you have a DLL with a string table as follows but where the Caption might vary depending on the target platform (Win32/x64) and configuration (Debug/Release) of the build:
Then in your calling application, you can have code as follows to extract the string table:
use iso_c_binding, only : c_int, c_char
use IWinAPI_m, only : LoadLibrary, LoadStringA, HMODULE, NULL_HANDLE
implicit none
! Local variables
integer(HMODULE) :: DllHandle
character(kind=c_char, len=256) :: DllString !<-- String of suitable length
integer(c_int) :: irc
! Load the DLL
DllHandle = LoadLibrary( c_char_"foo.dll" )
if ( DllHandle == NULL_HANDLE ) then
print *, "Failed to load the DLL"
stop
end if
! Load DLL string
irc = LoadStringA( DllHandle, uID=0, lpBuffer=DllString, cchBufferMax=len(DllString)-1 )
if ( irc > 0 ) then
print *, "DLL String: ", DllString(1:irc)
else
print *, "Failed to load DLL String."
end if
end
Upon execution with a sample DLL with different target platforms, the output for a debug version of Win32 target
DLL String: DEBUG_WIN32
and for a Release build of x64 target:
DLL String: RELEASE_X64
Bottom-line: my suggestion remains for you to use the same name DLL for your different combinations (similar to how Microsoft does with kernel32.dll, etc.) but instead fill the string table suitably based on Visual Studio macros (_DEBUG, etc.). Your calling application can then parse things out to inform the user re: the attributes of the DLL. You can have as many IDs and their Values and Captions as needed in your string table and you can use the values in LoadStringA function invocations to get the string information.
Here's some info on LoadLibrary you might find useful: https://stackoverflow.com/questions/3497516/does-loadlibrary-create-distinct-instances
